Die Sende- und Empfangshardware
Für 40 DM waren die Sender, für 80 DM die Empfänger zu bekommen. Die HF-Teile waren jeweils auf einer fertig aufgebauten Modulplatine vorhanden, das restliche Bausatzgemüse konnte man der Bastelkiste zuführen.
Sender/Empfänger waren allerdings wirklich billig - in jeder Hinsicht. Die 100m Reichweite sind allenfalls Wunschdenken, die angegebenen 20m unter gestörten - also realen - Bedingungen schon eher nachvollziehbar. Der Enable-Pin des Senders ist in Wirklichkeit die Spannungsversorgung. Dies hat zwei negative Nebeneffekte: nachdem man Enable gesetzt hat, muss der Empfänger sich noch ca. 15ms aufladen, einschwingen oder was auch immer, bevor er sendebereit ist. Des weiteren sendet das Modul nach Abschaltung des Enable einige Millisekunden willkürliche Signale, bevor es völlig entladen ist.
Das Empfangsmodul begnügt sich mit 5V. Auch das Sendemodul lässt sich mit 5V betreiben, der Maximalwert von 14V ist aber angebrachter, um die Reichweite zu erhöhen. Am einfachsten lässt sich der Sender über Optokoppler wie die 4N25 schalten, da diese grade genug Leistung bieten, um den Sender direkt anschließen zu können, im abgeschalteten Zustand praktisch keinen Strom verbrauchen, und zudem relativ klein sind.
Mit Batteriefach, ordentlich Platz im Innenraum und 21 Tasten, die über ein Folienkabel angeschlossen sind, ist dieser Typ für den Einbau einer eigenen Elektronik ausgezeichnet geeignet.
Der Empfänger zeigt sich ziemlich zickig bei Störungen auf der Eingangsleitung. Nach dem Einbau in ein Gehäuse aus miteinander verlöteten Leiterplatten mit Masseanschluss und der Filterung der Spannungsversorgung mittels Drosseln und Kondensatoren legt sich dieses Problem glücklicherweise.
Das Software-Konzept
Für die Fernbedienung, die die Grundlage für diese Beschreibung ist, genügen 16 Bit. Funkübertragungen, erst recht auf einem lizenzfreien Band, sind oft starken Störungen unterworfen.
Warum sich Gedanken machen, wenn eine zuverlässige Lösung längst existiert? Daher wird zur Fehlererkennung der CRC8-Algorithmus in der Implementierung von John Wren, gefunden auf www.8051.com, eingesetzt. Grob vereinfacht funktioniert dieser Algorithmus dadurch, dass die Datenbits durch einen Generatorwert geteilt werden. Der dabei übrigbleibende Rest ist nun die CRC-Prüfsumme. Weil 0 durch einen beliebigen Wert wieder 0 ergibt, und dabei Daten und Prüfsumme identisch wären, ist es angeraten, vor der Prüfsummenberechnung einen willkürlichen Startwert einzustellen.
zurück zum Anfang
Senden
INCLUDE crc8.inc INCLUDE time24.inc HFOUT EQU P3.1 HFEN EQU P3.0
HFOUT: Datenpin, Active Low
HFEN: Enable-Pin, Active Low
send_data:
push 0
push b
push Acc
clr HFEN
setb HFOUT
push Acc
mov a,#15
call F_wait_m
pop Acc
mov b,#10011101b
call crc8_add_calc
Radio_out:
mov R0,#8
clr HFOUT
call Radio_L3
call Radio_L3
nop
Radio_L2a:
rrc a
mov HFOUT,c
call Radio_L3
call Radio_L3
djnz R0,Radio_L2a
mov a, b
mov R0,#8
Radio_L2b:
rrc a
mov HFOUT,c
call Radio_L3
call Radio_L3
djnz R0,Radio_L2b
setb HFOUT
setb HFEN
pop Acc
pop b
pop 0
ret
Radio_L3:
push psw
push 0
mov 0,#92
Radio_L3_labelA:
djnz 0,Radio_L3_labelA
pop 0
pop psw
ret
Empfangen
Allerdings sieht eine Funk-Übertragung nicht so schön sauber aus wie eine kabelgebundene. In der Illustration, die oben die gesendeten und unten die empfangenen Signale abbildet, kann man einige Störungen im Empfänger erkennen.
Zum einen hat die Synchronisation mit dem Startbit nicht ganz geklappt, so sind die empfangenen Signale leicht auf der Zeitachse verschoben. Zum anderen sind die gesendeten Bits von Störungen unterbrochen. Bei nur einer Abfrage des Wertes pro Bit wäre es purer Zufall, ob das gesendete Signal oder eine Störung aufgezeichnet würde.
Das erste zu empfangende Bit ist das Startbit, welches immer 1 beziehungsweise ein gesendeter Puls sein muß, weil sich der Empfänger daran synchronisiert. Er weiß nach dem Erhalt des Startbits, dass noch 16 weitere Bits folgen. Auf den Empfang des Startbits wird in diesem Programmbeispiel in einer Schleife gewartet. Da diese Schleife aber nicht nur verlassen wird, wenn ein Startbit empfangen wird, sondern auch, wenn nur ein gesendeter Störungsimpuls eintrifft, würde der Empfänger daraufhin 16 Bitzeiten sinnlos mit dem Aufzeichnen von falschen Werten vertun. Damit dies nicht geschieht, wird auch das Startbit über dessen Bitzeit aufsummiert. Ist diese Summe kleiner als eine Konstante, so war es kein Startbit, sondern nur eine empfangene Störung; die Suche nach einem gültigen Startbit kann weitergehen.
zurück zum Anfang
INCLUDE crc8.inc
HFIN EQU P3.2
main:
Radio_in:
clr a
mov R0,#8
mov R1,#98
mov R2,a
mov R3,a
Radio_L0:
jnb HFIN,Radio_L0
Radio_L0a_innerLoop:
mov c,HFIN
addc a,#0
djnz R1,Radio_L0a_innerLoop
clr c
subb a,#60
jc main_error
Radio_L1a:
mov R1,#98
clr a
Radio_L1a_innerLoop:
mov c,HFIN
addc a,#0
djnz R1,Radio_L1a_innerLoop
clr c
subb a,#60
mov a,R2
rrc a
mov R2,a
djnz 0,Radio_L1a
mov R0,#8
Radio_L1b:
mov R1,#98
clr a
Radio_L1b_innerLoop:
mov c,HFIN
addc a,#0
djnz R1,Radio_L1b_innerLoop
clr c
subb a,#60
mov a,R3
rrc a
mov R3,a
djnz 0,Radio_L1b
mov a,R2
mov b,#10011101b
call crc8_add_calc
mov a,R3
xrl a,b
jnz main_error
; [Daten verarbeiten]
jmp main
main_error:
; [Fehlerbehandlung]
zurück zum Anfang
